nixos/xdg/autostart-entries: init

modules/nixos/default.nix

@@ -15,6 +15,7 @@
     ./services/wezterm-mux-server.nix
     ./services/vouch-proxy.nix
     ./services/yt-dlp.nix
+    ./xdg/autostart-entries.nix
     ./xdg/mime-desktop-specific.nix
     ./virtualisation/oci-containers
   ];

modules/nixos/xdg/autostart-entries.nix

@@ -0,0 +1,40 @@
+{ config, lib, pkgs, ... }:
+
+let
+  cfg = config.xdg.autostart;
+
+  xdgDesktopEntrySubmodule = { name, ... }: {
+    freeformType = with lib.types; attrsOf anything;
+  };
+in
+{
+  options.xdg.autostart.entries = lib.mkOption {
+    type = with lib.types; attrsOf (submodule xdgDesktopEntrySubmodule);
+    default = { };
+    description = ''
+      A set of XDG autostart entries to be exported to the environment.
+    '';
+    example = lib.literalExpression ''
+      {
+        kando = {
+          name = "kando";
+          desktopName = "Kando";
+          exec = lib.getExe pkgs.kando;
+          icon = "kando";
+          genericName = "Pie Menu";
+        };
+      }
+    '';
+  };
+
+  config = lib.mkIf (cfg.entries != { }) {
+    environment.systemPackages =
+      let
+        mkXDGAutostartFile = _: v:
+          pkgs.makeDesktopItem (v // {
+            destination = "/etc/xdg/autostart";
+          });
+      in
+      lib.mapAttrsToList mkXDGAutostartFile cfg.entries;
+  };
+}